# -*- tcl -*-
# idx_export_wiki.test:  tests for the doctools::idx::export::wiki package/plugin.
#
# Copyright (c) 2009 by Andreas Kupries <andreas_kupries@users.sourceforge.net>
# All rights reserved.
#
# RCS: @(#) $Id: export_wiki.test,v 1.1 2009/04/01 04:28:37 andreas_kupries Exp $

# -------------------------------------------------------------------------

source [file join \
	[file dirname [file dirname [file join [pwd] [info script]]]] \
	devtools testutilities.tcl]

testsNeedTcl     8.4
testsNeedTcltest 2.0

support {
    use      fileutil/fileutil.tcl  fileutil      ;# tests/common
    useLocal structure.tcl      doctools::idx::structure
    use doctools2base/text.tcl               doctools::text
}
testing {
    package provide doctools::idx::export::plugin 1
    # The above fakes the export plugin environment.

    useLocal export_wiki.tcl doctools::idx::export::wiki
}

source [tcllibPath doctools2base/tests/common]
set mytestdir tests/data

# -------------------------------------------------------------------------

# General set of error cases regarding the number of arguments.

test doctools-idx-export-wiki-1.0 {export, wrong#args} -body {
    export
} -returnCodes error -result {wrong # args: should be "export serial configuration"}

test doctools-idx-export-wiki-1.1 {export, wrong#args} -body {
    export S
} -returnCodes error -result {wrong # args: should be "export serial configuration"}

test doctools-idx-export-wiki-1.2 {export, wrong#args} -body {
    export S C XXX
} -returnCodes error -result {wrong # args: should be "export serial configuration"}

# -------------------------------------------------------------------------

# Testing the generation of wiki output, from index serialization,
# for all possible plugin configurations.

foreach {k style section} {
    0 list  -list
    1 table -table
} {
    TestFilesProcess $mytestdir ok serial wiki$section -> n label input data expected {
	test doctools-idx-export-wiki-2.$k.$n "doctools::idx::export::wiki, $label$section, ok" -setup {
	    set configuration [list style $style]
	} -body {
	    export $data $configuration
	} -cleanup {
	    unset configuration
	} -result $expected
    }
}

#----------------------------------------------------------------------
unset n label input data expected
testsuiteCleanup
return